plugins {
    id 'com.android.library'
    id 'maven-publish'
    id 'signing'
}

android {
    namespace 'com.saadahmedsoft.popupdialog'
    compileSdk 33

    defaultConfig {
        minSdk 21
        targetSdk 33

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        consumerProguardFiles "consumer-rules.pro"
    }

    publishing {
        singleVariant("release") {
            // if you don't want sources/javadoc, remove these lines
            withSourcesJar()
            withJavadocJar()
        }
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
}

task sourceJar(type: Jar) {
    from android.sourceSets.main.java.srcDirs
    classifier "sources"
}

def artifactVersion = "1.0.2"

publishing {
    publications {
        maven(MavenPublication) {
            groupId 'com.saadahmedev.popup-dialog'
            artifactId 'popup-dialog'
            version artifactVersion
            artifact(sourceJar)
            artifact("$buildDir/outputs/aar/popupDialog-release.aar")

            pom {
                name = 'Android Popup Dialog'
                description = 'A custom android popup dialog library which provides you a lot of popup dialog with and without animation'
                url = 'https://github.com/saadahmedscse/Android-Popup-Dialog'

                withXml {
                    def node = asNode().appendNode('dependencies').appendNode('dependency')
                    node.appendNode('groupId', 'com.airbnb.android')
                    node.appendNode('artifactId', 'lottie')
                    node.appendNode('version', '5.2.0')
                    node.appendNode('scope', 'compile')
                }

                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }
                developers {
                    developer {
                        id = 'saadahmedscse'
                        name = 'Saad Ahmed'
                        email = 'saadahmedscse@gmail.com'
                    }
                }
                scm {
                    connection = 'scm:git:git://github.com/saadahmedscse/Android-Popup-Dialog.git'
                    developerConnection = 'scm:git:ssh://github.com:saadahmedscse/Android-Popup-Dialog.git'
                    url = 'https://github.com/saadahmedscse/Android-Popup-Dialog'
                }
            }
        }
    }
    repositories {
        maven {
            def releaseUrl = "https://s01.oss.sonatype.org/content/repositories/releases/"
            def snapshotUrl = "https://s01.oss.sonatype.org/content/repositories/snapshots/"
            url = artifactVersion.endsWith('SNAPSHOT') ? snapshotUrl : releaseUrl

            credentials {
                username("username")
                password("password")
            }
        }
    }
}

dependencies {
    implementation 'androidx.appcompat:appcompat:1.5.1'
    implementation 'com.google.android.material:material:1.6.1'

    implementation "com.airbnb.android:lottie:5.2.0"
}

signing {
    sign configurations.archives
}